The upper 16 bit differ between signed and unsigned multiplication, so while

for 16x16=16, the unsigned routine can be used, regardless of signedness, this is not true for 16x16=32. git-svn-id: svn://svn.cc65.org/cc65/trunk@4438 b7a2c559-68d2-44c3-8de9-860c34a00d81
2009-11-04 13:45:27 +00:00
parent 1bec071755
commit 7c804513fa
3 changed files with 59 additions and 7 deletions
--- a/libsrc/runtime/umul16x16r32.s
+++ b/libsrc/runtime/umul16x16r32.s
@@ -0,0 +1,57 @@
+;
+; Ullrich von Bassewitz, 2010-11-03
+;
+; CC65 runtime: 16x16 => 32 unsigned multiplication
+;
+
+        .export         _cc65_umul16x16r32, umul16x16r32, umul16x16r32m
+        .import         popax
+    	.importzp      	ptr1, ptr3, sreg
+
+
+;---------------------------------------------------------------------------
+; 16x16 => 32 unsigned multiplication routine.
+;
+;   lhs         rhs           result          result also in
+; -------------------------------------------------------------
+;   ptr1        ax            ax:sreg          ptr1:sreg
+;
+
+_cc65_umul16x16r32:
+        sta     ptr1
+        stx     ptr1+1
+        jsr     popax
+
+umul16x16r32:
+        sta     ptr3
+        stx     ptr3+1
+
+umul16x16r32m:
+       	lda	#0
+       	sta    	sreg+1
+       	ldy    	#16   	       	; Number of bits
+
+        lsr     ptr1+1
+        ror     ptr1            ; Get first bit into carry
+@L0:    bcc     @L1
+
+      	clc
+      	adc	ptr3
+      	pha
+       	lda     ptr3+1
+      	adc	sreg+1
+      	sta	sreg+1
+      	pla
+
+@L1:    ror     sreg+1
+     	ror	a
+     	ror	ptr1+1
+     	ror	ptr1
+        dey
+        bne     @L0
+
+        sta     sreg            ; Save byte 3
+      	lda	ptr1	       	; Load the result
+      	ldx	ptr1+1
+      	rts	    		; Done
+