more cleanup, joystick works again

libsrc/pce/joy/pce-stdjoy.s

@@ -0,0 +1,162 @@
+
+;
+; Standard joystick driver for the PCEngine
+;
+
+        .include        "joy-kernel.inc"
+        .include        "joy-error.inc"
+
+        .macpack        module
+
+
+; ------------------------------------------------------------------------
+; Header. Includes jump table
+
+        module_header   _pce_stdjoy_joy
+
+; Driver signature
+
+        .byte   $6A, $6F, $79           ; "joy"
+        .byte   JOY_API_VERSION         ; Driver API version number
+
+; Library reference
+
+        .addr   $0000
+
+; Button state masks (8 values)
+
+;extern const unsigned char joy_masks[8];
+
+        .export _joy_masks
+
+_joy_masks:
+        .byte   $10                     ; JOY_UP
+        .byte   $40                     ; JOY_DOWN
+        .byte   $80                     ; JOY_LEFT
+        .byte   $20                     ; JOY_RIGHT
+        .byte   $02                     ; JOY_FIRE A  ; FIXME: is this correct?
+        .byte   $01                     ; JOY_FIRE B  ; FIXME: is this correct?
+        .byte   $04                     ; JOY_START   ; FIXME: is this correct?
+        .byte   $08                     ; JOY_SELECT  ; FIXME: is this correct?
+
+; Jump table.
+
+        .addr   INSTALL
+        .addr   UNINSTALL
+        .addr   COUNT
+        .addr   READJOY
+        .addr   0                       ; IRQ entry unused
+
+; ------------------------------------------------------------------------
+; Constants
+
+JOY_COUNT       = 4             ; Number of joysticks we support
+
+
+.code
+
+; ------------------------------------------------------------------------
+; INSTALL routine. Is called after the driver is loaded into memory. If
+; possible, check if the hardware is present and determine the amount of
+; memory available.
+; Must return an JOY_ERR_xx code in a/x.
+;
+
+INSTALL:
+                lda     #<JOY_ERR_OK
+                ldx     #>JOY_ERR_OK
+
+;               rts                     ; Run into DEINSTALL instead
+
+; ------------------------------------------------------------------------
+; DEINSTALL routine. Is called before the driver is removed from memory.
+; Can do cleanup or whatever. Must not return anything.
+;
+
+UNINSTALL:
+                rts
+
+
+; ------------------------------------------------------------------------
+; COUNT: Return the total number of available joysticks in a/x.
+;
+;unsigned char __fastcall__ joy_count (void);
+
+COUNT:
+                lda     #<JOY_COUNT
+                ldx     #>JOY_COUNT
+                rts
+
+; ------------------------------------------------------------------------
+; READ: Read a particular joystick passed in A.
+;
+;unsigned char __fastcall__ joy_read (unsigned char joystick);
+
+READJOY:
+                pha
+                jsr read_joy
+                pla
+                tax             ; Joystick number into X
+
+                ; return value from buffer
+
+joy1:
+                lda padbuffer,x
+                ldx #0
+                rts
+
+read_joy:
+                ; reset multitap counter
+                lda     #$01
+                sta     $1000
+                pha
+                pla
+                nop
+                nop
+
+                lda     #$03
+                sta     $1000
+                pha
+                pla
+                nop
+                nop
+
+                cly
+nextpad:
+                lda     #$01
+                sta     $1000   ; sel = 1
+                pha
+                pla
+                nop
+                nop
+
+                lda     $1000
+                asl     a
+                asl     a
+                asl     a
+                asl     a
+                sta     padbuffer, y     ; store new value
+
+                stz     $1000
+                pha
+                pla
+                nop
+                nop
+
+                lda     $1000
+                and     #$0F
+                ora     padbuffer, y     ; second half of new value
+
+                eor     #$FF
+                sta     padbuffer, y     ; store new value
+
+                iny
+                cpy     #$05
+                bcc     nextpad
+                rts
+
+.bss
+
+padbuffer:
+                .res 4
+