diff --git a/README.md b/README.md
index 9a55b64..fb6869b 100644
--- a/README.md
+++ b/README.md
@@ -42,6 +42,7 @@ To facilitate the dual-license model, contributions to the project can only be a
     *  Combined FIFO + width converter
     *  Combined async FIFO + width converter
     *  Multiplexer
+    *  Demultiplexer
     *  Broadcaster
     *  Concatenator
     *  COBS encoder
diff --git a/src/axis/rtl/taxi_axis_demux.sv b/src/axis/rtl/taxi_axis_demux.sv
new file mode 100644
index 0000000..42daec1
--- /dev/null
+++ b/src/axis/rtl/taxi_axis_demux.sv
@@ -0,0 +1,280 @@
+// SPDX-License-Identifier: CERN-OHL-S-2.0
+/*
+
+Copyright (c) 2018-2025 FPGA Ninja, LLC
+
+Authors:
+- Alex Forencich
+
+*/
+
+`resetall
+`timescale 1ns / 1ps
+`default_nettype none
+
+/*
+ * AXI4-Stream demultiplexer
+ */
+module taxi_axis_demux #
+(
+    // Number of AXI stream outputs
+    parameter M_COUNT = 4,
+    // route via tdest
+    parameter logic TDEST_ROUTE = 1'b0
+)
+(
+    input  wire logic                        clk,
+    input  wire logic                        rst,
+
+    /*
+     * AXI4-Stream input (sink)
+     */
+    taxi_axis_if.snk                         s_axis,
+
+    /*
+     * AXI4-Stream output (source)
+     */
+    taxi_axis_if.src                         m_axis[M_COUNT],
+
+    /*
+     * Control
+     */
+    input  wire logic                        enable,
+    input  wire logic                        drop,
+    input  wire logic [$clog2(M_COUNT)-1:0]  select
+);
+
+// extract parameters
+localparam DATA_W = s_axis.DATA_W;
+localparam logic KEEP_EN = s_axis.KEEP_EN && m_axis[0].KEEP_EN;
+localparam KEEP_W = s_axis.KEEP_W;
+localparam logic STRB_EN = s_axis.STRB_EN && m_axis[0].STRB_EN;
+localparam logic LAST_EN = s_axis.LAST_EN && m_axis[0].LAST_EN;
+localparam logic ID_EN = s_axis.ID_EN && m_axis[0].ID_EN;
+localparam ID_W = s_axis.ID_W;
+localparam logic DEST_EN = s_axis.DEST_EN && m_axis[0].DEST_EN;
+localparam S_DEST_W = s_axis.DEST_W;
+localparam M_DEST_W = m_axis[0].DEST_W;
+localparam logic USER_EN = s_axis.USER_EN && m_axis[0].USER_EN;
+localparam USER_W = s_axis.USER_W;
+
+localparam CL_M_COUNT = $clog2(M_COUNT);
+
+localparam M_DEST_W_INT = M_DEST_W > 0 ? M_DEST_W : 1;
+
+// check configuration
+if (m_axis[0].DATA_W != DATA_W)
+    $fatal(0, "Error: Interface DATA_W parameter mismatch (instance %m)");
+
+if (KEEP_EN && m_axis[0].KEEP_W != KEEP_W)
+    $fatal(0, "Error: Interface KEEP_W parameter mismatch (instance %m)");
+
+if (TDEST_ROUTE) begin
+    if (!DEST_EN)
+        $fatal(0, "Error: TDEST_ROUTE set requires DEST_EN set (instance %m)");
+
+    if (S_DEST_W < CL_M_COUNT)
+        $fatal(0, "Error: S_DEST_W too small for port count (instance %m)");
+end
+
+logic [CL_M_COUNT-1:0] select_reg = '0, select_ctl, select_next;
+logic drop_reg = 1'b0, drop_ctl, drop_next;
+logic frame_reg = 1'b0, frame_ctl, frame_next;
+
+logic s_axis_tready_reg = 1'b0, s_axis_tready_next;
+
+// internal datapath
+logic [DATA_W-1:0]    m_axis_tdata_int;
+logic [KEEP_W-1:0]    m_axis_tkeep_int;
+logic [KEEP_W-1:0]    m_axis_tstrb_int;
+logic [M_COUNT-1:0]   m_axis_tvalid_int;
+logic                 m_axis_tready_int_reg = 1'b0;
+logic                 m_axis_tlast_int;
+logic [ID_W-1:0]      m_axis_tid_int;
+logic [M_DEST_W-1:0]  m_axis_tdest_int;
+logic [USER_W-1:0]    m_axis_tuser_int;
+wire                  m_axis_tready_int_early;
+
+assign s_axis.tready = s_axis_tready_reg && enable;
+
+always_comb begin
+    select_next = select_reg;
+    select_ctl = select_reg;
+    drop_next = drop_reg;
+    drop_ctl = drop_reg;
+    frame_next = frame_reg;
+    frame_ctl = frame_reg;
+
+    if (s_axis.tvalid && s_axis.tready) begin
+        // end of frame detection
+        if (s_axis.tlast) begin
+            frame_next = 1'b0;
+            drop_next = 1'b0;
+        end
+    end
+
+    if (!frame_reg && s_axis.tvalid && s_axis.tready) begin
+        // start of frame, grab select value
+        if (TDEST_ROUTE) begin
+            if (M_COUNT > 1) begin
+                select_ctl = s_axis.tdest[S_DEST_W-1:S_DEST_W-CL_M_COUNT];
+                drop_ctl = (CL_M_COUNT+1)'(select_ctl) >= (CL_M_COUNT+1)'(M_COUNT);
+            end else begin
+                select_ctl = '0;
+                drop_ctl = 1'b0;
+            end
+        end else begin
+            select_ctl = select;
+            drop_ctl = drop || (CL_M_COUNT+1)'(select) >= (CL_M_COUNT+1)'(M_COUNT);
+        end
+        frame_ctl = 1'b1;
+        if (!(s_axis.tready && s_axis.tvalid && s_axis.tlast)) begin
+            select_next = select_ctl;
+            drop_next = drop_ctl;
+            frame_next = 1'b1;
+        end
+    end
+
+    m_axis_tdata_int  = s_axis.tdata;
+    m_axis_tkeep_int  = s_axis.tkeep;
+    m_axis_tstrb_int  = s_axis.tstrb;
+    m_axis_tvalid_int = '0;
+    m_axis_tvalid_int[select_ctl] = s_axis.tvalid && s_axis.tready && !drop_ctl;
+    m_axis_tlast_int  = s_axis.tlast;
+    m_axis_tid_int    = s_axis.tid;
+    m_axis_tdest_int  = M_DEST_W'(s_axis.tdest);
+    m_axis_tuser_int  = s_axis.tuser;
+end
+
+always_comb begin
+    s_axis_tready_next = (m_axis_tready_int_early || drop_ctl);
+end
+
+always_ff @(posedge clk) begin
+    select_reg <= select_next;
+    drop_reg <= drop_next;
+    frame_reg <= frame_next;
+    s_axis_tready_reg <= s_axis_tready_next;
+
+    if (rst) begin
+        select_reg <= '0;
+        drop_reg <= 1'b0;
+        frame_reg <= 1'b0;
+        s_axis_tready_reg <= 1'b0;
+    end
+end
+
+// output datapath logic
+logic [DATA_W-1:0]    m_axis_tdata_reg  = '0;
+logic [KEEP_W-1:0]    m_axis_tkeep_reg  = '0;
+logic [KEEP_W-1:0]    m_axis_tstrb_reg  = '0;
+logic [M_COUNT-1:0]   m_axis_tvalid_reg = '0, m_axis_tvalid_next;
+logic                 m_axis_tlast_reg  = 1'b0;
+logic [ID_W-1:0]      m_axis_tid_reg    = '0;
+logic [M_DEST_W-1:0]  m_axis_tdest_reg  = '0;
+logic [USER_W-1:0]    m_axis_tuser_reg  = '0;
+
+logic [DATA_W-1:0]    temp_m_axis_tdata_reg  = '0;
+logic [KEEP_W-1:0]    temp_m_axis_tkeep_reg  = '0;
+logic [KEEP_W-1:0]    temp_m_axis_tstrb_reg  = '0;
+logic [M_COUNT-1:0]   temp_m_axis_tvalid_reg = '0, temp_m_axis_tvalid_next;
+logic                 temp_m_axis_tlast_reg  = 1'b0;
+logic [ID_W-1:0]      temp_m_axis_tid_reg    = '0;
+logic [M_DEST_W-1:0]  temp_m_axis_tdest_reg  = '0;
+logic [USER_W-1:0]    temp_m_axis_tuser_reg  = '0;
+
+// datapath control
+logic store_axis_int_to_output;
+logic store_axis_int_to_temp;
+logic store_axis_temp_to_output;
+
+wire [M_COUNT-1:0] m_axis_tready;
+
+for (genvar k = 0; k < M_COUNT; k = k + 1) begin
+    assign m_axis[k].tdata  = m_axis_tdata_reg;
+    assign m_axis[k].tkeep  = KEEP_EN ? m_axis_tkeep_reg : '1;
+    assign m_axis[k].tstrb  = STRB_EN ? m_axis_tstrb_reg : m_axis[k].tkeep;
+    assign m_axis[k].tvalid = m_axis_tvalid_reg[k];
+    assign m_axis[k].tlast  = m_axis_tlast_reg;
+    assign m_axis[k].tid    = ID_EN   ? m_axis_tid_reg   : '0;
+    assign m_axis[k].tdest  = DEST_EN ? m_axis_tdest_reg : '0;
+    assign m_axis[k].tuser  = USER_EN ? m_axis_tuser_reg : '0;
+
+    assign m_axis_tready[k] = m_axis[k].tready;
+end
+
+// enable ready input next cycle if output is ready or the temp reg will not be filled on the next cycle (output reg empty or no input)
+assign m_axis_tready_int_early = (m_axis_tready & m_axis_tvalid_reg) != 0 || (temp_m_axis_tvalid_reg == 0 && (m_axis_tvalid_reg == 0 || m_axis_tvalid_int == 0));
+
+always_comb begin
+    // transfer sink ready state to source
+    m_axis_tvalid_next = m_axis_tvalid_reg;
+    temp_m_axis_tvalid_next = temp_m_axis_tvalid_reg;
+
+    store_axis_int_to_output = 1'b0;
+    store_axis_int_to_temp = 1'b0;
+    store_axis_temp_to_output = 1'b0;
+
+    if (m_axis_tready_int_reg) begin
+        // input is ready
+        if ((m_axis_tready & m_axis_tvalid_reg) != 0 || m_axis_tvalid_reg == 0) begin
+            // output is ready or currently not valid, transfer data to output
+            m_axis_tvalid_next = m_axis_tvalid_int;
+            store_axis_int_to_output = 1'b1;
+        end else begin
+            // output is not ready, store input in temp
+            temp_m_axis_tvalid_next = m_axis_tvalid_int;
+            store_axis_int_to_temp = 1'b1;
+        end
+    end else if ((m_axis_tready & m_axis_tvalid_reg) != 0) begin
+        // input is not ready, but output is ready
+        m_axis_tvalid_next = temp_m_axis_tvalid_reg;
+        temp_m_axis_tvalid_next = '0;
+        store_axis_temp_to_output = 1'b1;
+    end
+end
+
+always_ff @(posedge clk) begin
+    m_axis_tvalid_reg <= m_axis_tvalid_next;
+    m_axis_tready_int_reg <= m_axis_tready_int_early;
+    temp_m_axis_tvalid_reg <= temp_m_axis_tvalid_next;
+
+    // datapath
+    if (store_axis_int_to_output) begin
+        m_axis_tdata_reg <= m_axis_tdata_int;
+        m_axis_tkeep_reg <= m_axis_tkeep_int;
+        m_axis_tstrb_reg <= m_axis_tstrb_int;
+        m_axis_tlast_reg <= m_axis_tlast_int;
+        m_axis_tid_reg   <= m_axis_tid_int;
+        m_axis_tdest_reg <= m_axis_tdest_int;
+        m_axis_tuser_reg <= m_axis_tuser_int;
+    end else if (store_axis_temp_to_output) begin
+        m_axis_tdata_reg <= temp_m_axis_tdata_reg;
+        m_axis_tkeep_reg <= temp_m_axis_tkeep_reg;
+        m_axis_tstrb_reg <= temp_m_axis_tstrb_reg;
+        m_axis_tlast_reg <= temp_m_axis_tlast_reg;
+        m_axis_tid_reg   <= temp_m_axis_tid_reg;
+        m_axis_tdest_reg <= temp_m_axis_tdest_reg;
+        m_axis_tuser_reg <= temp_m_axis_tuser_reg;
+    end
+
+    if (store_axis_int_to_temp) begin
+        temp_m_axis_tdata_reg <= m_axis_tdata_int;
+        temp_m_axis_tkeep_reg <= m_axis_tkeep_int;
+        temp_m_axis_tstrb_reg <= m_axis_tstrb_int;
+        temp_m_axis_tlast_reg <= m_axis_tlast_int;
+        temp_m_axis_tid_reg   <= m_axis_tid_int;
+        temp_m_axis_tdest_reg <= m_axis_tdest_int;
+        temp_m_axis_tuser_reg <= m_axis_tuser_int;
+    end
+
+    if (rst) begin
+        m_axis_tvalid_reg <= '0;
+        m_axis_tready_int_reg <= 1'b0;
+        temp_m_axis_tvalid_reg <= '0;
+    end
+end
+
+endmodule
+
+`resetall
diff --git a/src/axis/tb/taxi_axis_demux/Makefile b/src/axis/tb/taxi_axis_demux/Makefile
new file mode 100644
index 0000000..86b59e0
--- /dev/null
+++ b/src/axis/tb/taxi_axis_demux/Makefile
@@ -0,0 +1,66 @@
+# SPDX-License-Identifier: CERN-OHL-S-2.0
+#
+# Copyright (c) 2021-2025 FPGA Ninja, LLC
+#
+# Authors:
+# - Alex Forencich
+
+TOPLEVEL_LANG = verilog
+
+SIM ?= verilator
+WAVES ?= 0
+
+COCOTB_HDL_TIMEUNIT = 1ns
+COCOTB_HDL_TIMEPRECISION = 1ps
+
+RTL_DIR = ../../rtl
+LIB_DIR = ../../lib
+TAXI_SRC_DIR = $(LIB_DIR)/taxi/src
+
+DUT      = taxi_axis_demux
+COCOTB_TEST_MODULES = test_$(DUT)
+COCOTB_TOPLEVEL     = test_$(DUT)
+MODULE   = $(COCOTB_TEST_MODULES)
+TOPLEVEL = $(COCOTB_TOPLEVEL)
+VERILOG_SOURCES += $(COCOTB_TOPLEVEL).sv
+VERILOG_SOURCES += $(RTL_DIR)/$(DUT).sv
+VERILOG_SOURCES += $(RTL_DIR)/taxi_axis_if.sv
+
+# handle file list files
+process_f_file = $(call process_f_files,$(addprefix $(dir $1),$(shell cat $1)))
+process_f_files = $(foreach f,$1,$(if $(filter %.f,$f),$(call process_f_file,$f),$f))
+uniq_base = $(if $1,$(call uniq_base,$(foreach f,$1,$(if $(filter-out $(notdir $(lastword $1)),$(notdir $f)),$f,))) $(lastword $1))
+VERILOG_SOURCES := $(call uniq_base,$(call process_f_files,$(VERILOG_SOURCES)))
+
+# module parameters
+export PARAM_M_COUNT := 4
+export PARAM_DATA_W := 8
+export PARAM_KEEP_EN := $(shell expr $(PARAM_DATA_W) \> 8 )
+export PARAM_KEEP_W := $(shell expr \( $(PARAM_DATA_W) + 7 \) / 8 )
+export PARAM_STRB_EN := 0
+export PARAM_LAST_EN := 1
+export PARAM_ID_EN := 1
+export PARAM_ID_W := 8
+export PARAM_DEST_EN := 1
+export PARAM_M_DEST_W := 8
+export PARAM_S_DEST_W := $(shell python -c "print($(PARAM_M_DEST_W) + ($(PARAM_M_COUNT)-1).bit_length())")
+export PARAM_USER_EN := 1
+export PARAM_USER_W := 1
+export PARAM_TDEST_ROUTE := 1
+
+ifeq ($(SIM), icarus)
+	PLUSARGS += -fst
+
+	COMPILE_ARGS += $(foreach v,$(filter PARAM_%,$(.VARIABLES)),-P $(COCOTB_TOPLEVEL).$(subst PARAM_,,$(v))=$($(v)))
+else ifeq ($(SIM), verilator)
+# 	COMPILE_ARGS += -Wno-SELRANGE -Wno-WIDTH
+
+	COMPILE_ARGS += $(foreach v,$(filter PARAM_%,$(.VARIABLES)),-G$(subst PARAM_,,$(v))=$($(v)))
+
+	ifeq ($(WAVES), 1)
+		COMPILE_ARGS += --trace-fst
+		VERILATOR_TRACE = 1
+	endif
+endif
+
+include $(shell cocotb-config --makefiles)/Makefile.sim
diff --git a/src/axis/tb/taxi_axis_demux/test_taxi_axis_demux.py b/src/axis/tb/taxi_axis_demux/test_taxi_axis_demux.py
new file mode 100644
index 0000000..82993a1
--- /dev/null
+++ b/src/axis/tb/taxi_axis_demux/test_taxi_axis_demux.py
@@ -0,0 +1,208 @@
+#!/usr/bin/env python
+# SPDX-License-Identifier: CERN-OHL-S-2.0
+"""
+
+Copyright (c) 2021-2025 FPGA Ninja, LLC
+
+Authors:
+- Alex Forencich
+
+"""
+
+import itertools
+import logging
+import os
+
+import cocotb_test.simulator
+import pytest
+
+import cocotb
+from cocotb.clock import Clock
+from cocotb.triggers import RisingEdge
+from cocotb.regression import TestFactory
+
+from cocotbext.axi import AxiStreamBus, AxiStreamFrame, AxiStreamSource, AxiStreamSink
+
+
+class TB(object):
+    def __init__(self, dut):
+        self.dut = dut
+
+        self.log = logging.getLogger("cocotb.tb")
+        self.log.setLevel(logging.DEBUG)
+
+        cocotb.start_soon(Clock(dut.clk, 10, units="ns").start())
+
+        self.source = AxiStreamSource(AxiStreamBus.from_entity(dut.s_axis), dut.clk, dut.rst)
+        self.sink = [AxiStreamSink(AxiStreamBus.from_entity(bus), dut.clk, dut.rst) for bus in dut.m_axis]
+
+        dut.enable.setimmediatevalue(0)
+        dut.drop.setimmediatevalue(0)
+        dut.select.setimmediatevalue(0)
+
+    def set_idle_generator(self, generator=None):
+        if generator:
+            self.source.set_pause_generator(generator())
+
+    def set_backpressure_generator(self, generator=None):
+        if generator:
+            for sink in self.sink:
+                sink.set_pause_generator(generator())
+
+    async def reset(self):
+        self.dut.rst.setimmediatevalue(0)
+        await RisingEdge(self.dut.clk)
+        await RisingEdge(self.dut.clk)
+        self.dut.rst.value = 1
+        await RisingEdge(self.dut.clk)
+        await RisingEdge(self.dut.clk)
+        self.dut.rst.value = 0
+        await RisingEdge(self.dut.clk)
+        await RisingEdge(self.dut.clk)
+
+
+async def run_test(dut, payload_lengths=None, payload_data=None, idle_inserter=None, backpressure_inserter=None, port=0):
+
+    tb = TB(dut)
+
+    id_width = len(tb.source.bus.tid)
+    id_count = 2**id_width
+    id_mask = id_count-1
+
+    dest_width = len(tb.sink[0].bus.tid)
+    dest_count = 2**dest_width
+    dest_mask = dest_count-1
+
+    cur_id = 1
+
+    await tb.reset()
+
+    tb.set_idle_generator(idle_inserter)
+    tb.set_backpressure_generator(backpressure_inserter)
+
+    test_frames = []
+
+    dut.enable.setimmediatevalue(1)
+    dut.drop.setimmediatevalue(0)
+    dut.select.setimmediatevalue(port)
+
+    for test_data in [payload_data(x) for x in payload_lengths()]:
+        test_frame = AxiStreamFrame(test_data)
+        test_frame.tid = cur_id
+        test_frame.tdest = cur_id | (port << dest_width)
+
+        test_frames.append(test_frame)
+        await tb.source.send(test_frame)
+
+        cur_id = (cur_id + 1) % id_count
+
+    for test_frame in test_frames:
+        rx_frame = await tb.sink[port].recv()
+
+        assert rx_frame.tdata == test_frame.tdata
+        assert rx_frame.tid == test_frame.tid
+        assert rx_frame.tdest == (test_frame.tdest & dest_mask)
+        assert not rx_frame.tuser
+
+    assert tb.sink[port].empty()
+
+    await RisingEdge(dut.clk)
+    await RisingEdge(dut.clk)
+
+
+def cycle_pause():
+    return itertools.cycle([1, 1, 1, 0])
+
+
+def size_list():
+    data_width = len(cocotb.top.s_axis.tdata)
+    byte_width = data_width // 8
+    return list(range(1, byte_width*4+1))+[512]+[1]*64
+
+
+def incrementing_payload(length):
+    return bytearray(itertools.islice(itertools.cycle(range(256)), length))
+
+
+if cocotb.SIM_NAME:
+
+    ports = len(cocotb.top.m_axis)
+
+    factory = TestFactory(run_test)
+    factory.add_option("payload_lengths", [size_list])
+    factory.add_option("payload_data", [incrementing_payload])
+    factory.add_option("idle_inserter", [None, cycle_pause])
+    factory.add_option("backpressure_inserter", [None, cycle_pause])
+    factory.add_option("port", list(range(ports)))
+    factory.generate_tests()
+
+
+# cocotb-test
+
+tests_dir = os.path.dirname(__file__)
+rtl_dir = os.path.abspath(os.path.join(tests_dir, '..', '..', 'rtl'))
+lib_dir = os.path.abspath(os.path.join(tests_dir, '..', '..', 'lib'))
+taxi_src_dir = os.path.abspath(os.path.join(lib_dir, 'taxi', 'src'))
+
+
+def process_f_files(files):
+    lst = {}
+    for f in files:
+        if f[-2:].lower() == '.f':
+            with open(f, 'r') as fp:
+                l = fp.read().split()
+            for f in process_f_files([os.path.join(os.path.dirname(f), x) for x in l]):
+                lst[os.path.basename(f)] = f
+        else:
+            lst[os.path.basename(f)] = f
+    return list(lst.values())
+
+
+@pytest.mark.parametrize("tdest_route", [0, 1])
+@pytest.mark.parametrize("data_w", [8, 16, 32])
+@pytest.mark.parametrize("m_count", [4])
+def test_taxi_axis_demux(request, m_count, data_w, tdest_route):
+    dut = "taxi_axis_demux"
+    module = os.path.splitext(os.path.basename(__file__))[0]
+    toplevel = module
+
+    verilog_sources = [
+        os.path.join(tests_dir, f"{toplevel}.sv"),
+        os.path.join(rtl_dir, f"{dut}.sv"),
+        os.path.join(rtl_dir, "taxi_axis_if.sv"),
+    ]
+
+    verilog_sources = process_f_files(verilog_sources)
+
+    parameters = {}
+
+    parameters['M_COUNT'] = m_count
+    parameters['DATA_W'] = data_w
+    parameters['KEEP_EN'] = int(parameters['DATA_W'] > 8)
+    parameters['KEEP_W'] = (parameters['DATA_W'] + 7) // 8
+    parameters['STRB_EN'] = 0
+    parameters['LAST_EN'] = 1
+    parameters['ID_EN'] = 1
+    parameters['ID_W'] = 8
+    parameters['DEST_EN'] = 1
+    parameters['M_DEST_W'] = 8
+    parameters['S_DEST_W'] = parameters['M_DEST_W'] + (m_count-1).bit_length()
+    parameters['USER_EN'] = 1
+    parameters['USER_W'] = 1
+    parameters['TDEST_ROUTE'] = tdest_route
+
+    extra_env = {f'PARAM_{k}': str(v) for k, v in parameters.items()}
+
+    sim_build = os.path.join(tests_dir, "sim_build",
+        request.node.name.replace('[', '-').replace(']', ''))
+
+    cocotb_test.simulator.run(
+        simulator="verilator",
+        python_search=[tests_dir],
+        verilog_sources=verilog_sources,
+        toplevel=toplevel,
+        module=module,
+        parameters=parameters,
+        sim_build=sim_build,
+        extra_env=extra_env,
+    )
diff --git a/src/axis/tb/taxi_axis_demux/test_taxi_axis_demux.sv b/src/axis/tb/taxi_axis_demux/test_taxi_axis_demux.sv
new file mode 100644
index 0000000..6c08269
--- /dev/null
+++ b/src/axis/tb/taxi_axis_demux/test_taxi_axis_demux.sv
@@ -0,0 +1,102 @@
+// SPDX-License-Identifier: CERN-OHL-S-2.0
+/*
+
+Copyright (c) 2025 FPGA Ninja, LLC
+
+Authors:
+- Alex Forencich
+
+*/
+
+`resetall
+`timescale 1ns / 1ps
+`default_nettype none
+
+/*
+ * AXI4-Stream demultiplexer testbench
+ */
+module test_taxi_axis_demux #
+(
+    /* verilator lint_off WIDTHTRUNC */
+    parameter M_COUNT = 4,
+    parameter DATA_W = 8,
+    parameter logic KEEP_EN = (DATA_W>8),
+    parameter KEEP_W = ((DATA_W+7)/8),
+    parameter logic STRB_EN = 1'b0,
+    parameter logic LAST_EN = 1'b1,
+    parameter logic ID_EN = 1'b0,
+    parameter ID_W = 8,
+    parameter logic DEST_EN = 1'b0,
+    parameter M_DEST_W = 8,
+    parameter S_DEST_W = M_DEST_W+$clog2(M_COUNT),
+    parameter logic USER_EN = 1'b1,
+    parameter USER_W = 1,
+    parameter logic TDEST_ROUTE = 1'b0
+    /* verilator lint_on WIDTHTRUNC */
+)
+();
+
+logic clk;
+logic rst;
+
+taxi_axis_if #(
+    .DATA_W(DATA_W),
+    .KEEP_EN(KEEP_EN),
+    .KEEP_W(KEEP_W),
+    .STRB_EN(STRB_EN),
+    .LAST_EN(LAST_EN),
+    .ID_EN(ID_EN),
+    .ID_W(ID_W),
+    .DEST_EN(DEST_EN),
+    .DEST_W(S_DEST_W),
+    .USER_EN(USER_EN),
+    .USER_W(USER_W)
+) s_axis();
+
+taxi_axis_if #(
+    .DATA_W(DATA_W),
+    .KEEP_EN(KEEP_EN),
+    .KEEP_W(KEEP_W),
+    .STRB_EN(STRB_EN),
+    .LAST_EN(LAST_EN),
+    .ID_EN(ID_EN),
+    .ID_W(ID_W),
+    .DEST_EN(DEST_EN),
+    .DEST_W(M_DEST_W),
+    .USER_EN(USER_EN),
+    .USER_W(USER_W)
+) m_axis[M_COUNT]();
+
+logic enable;
+logic drop;
+logic [$clog2(M_COUNT)-1:0] select;
+
+taxi_axis_demux #(
+    .M_COUNT(M_COUNT),
+    .TDEST_ROUTE(TDEST_ROUTE)
+)
+uut (
+    .clk(clk),
+    .rst(rst),
+
+    /*
+     * AXI4-Stream input (sink)
+     */
+    .s_axis(s_axis),
+
+    /*
+     * AXI4-Stream output (source)
+     */
+    .m_axis(m_axis),
+
+    /*
+     * Control
+     */
+    .enable(enable),
+    .drop(drop),
+    .select(select)
+);
+
+endmodule
+
+`resetall